pomoc oko resourcea

[ krp4 @ 01.08.2005. 02:02 ] @

dali je moguce da ubacim neku sliku u resource. mislim iz gotovog exe fajla u taj isti exe (npr. ja u exe fajlu izaberem neku sliku i nju spremim u resource, tako da ju uvjek mogu citati iz resourcea)

[ Aleksandar Ružičić @ 01.08.2005. 03:17 ] @

naravno:

Code:

Me.Picture = LoadResPicture(101, vbResBitmap)

gde ti je 101 id slike u resource-u

[ krp4 @ 01.08.2005. 17:09 ] @

ja ne zelim ucitati sliku iz resourcea nego ju spremiti u resource. (ako je to moguce)

[ Aleksandar Ružičić @ 01.08.2005. 20:04 ] @

pa sve je moguce (i sve nije moguce :p) samo sto bi to bilo malo teze.
a da dodas taj resource u tvoj exe mogu slobodno da ti kazem da NEMA POJMA TO DA SE URADI IZ VB-a (a pitanje je da li bi moglo i iz c-a).
a ako hoces samo da dodas sliku u .res faj onda ti je najlakse da koristis rc.exe i njemu da tvoj program generise .rc skript (koji rc.exe kompiluje u .res) mada mi nije jasno zasto bi radio tako nesto. mnogo jednostavnije bi ti bilo da slike cuvas u nekom svom formatu...

[ Pr[o_O]F @ 01.08.2005. 21:16 ] @

Mozda da ucitas sliku na kraj EXE fajla?

[ hatebreeder @ 01.08.2005. 22:55 ] @

pa nije da nije moguce, res fajl je pored EXE-a tako da je logicno da moze se dopuni probacu nesto da napsem pa cu okaciti kod

[ Aleksandar Ružičić @ 02.08.2005. 00:06 ] @

za dodavanje fajla na kraj exe-a pogledaj ovo

Citat:

hatebreeder: pa nije da nije moguce, res fajl je pored EXE-a tako da je logicno da moze se dopuni probacu nesto da napsem pa cu okaciti kod

kako mislis "pored"?
kad kompilujes exe onda ti je resource "ubacen" u taj exe fajl (dakle nije potrebno da pored .exe imas i .res)

[ krp4 @ 02.08.2005. 00:33 ] @

sad vidim koliko je to komplicirano, a dali bi se slike (i text) mogle spremati u neku bazu ili slicno? nemam bas niakvog iskustva s bazama pa moze mala pomoc ili neki linkovi. hvala

[ Aleksandar Ružičić @ 02.08.2005. 01:15 ] @

naravno da bi mogli ali ako nisi dosad radio sa bazama ja bih ti preporucio nesto jednostavnije:
ubaci ovaj kod u modul:

Code:

Option Explicit

Public Sub WriteData(sFile As String, Entry As String, Value As Variant)
    Dim propBag     As New PropertyBag
    Dim varData     As Variant
    Dim b()         As Byte
    Dim ff          As Integer

    If Dir(sFile) <> vbNullString Then
        ff = FreeFile
        Open sFile For Binary As #ff
            Get #ff, , varData
        Close #ff
        b = varData
        propBag.Contents = b
        On Error Resume Next
        Call Kill(sFile)
    End If

    Call propBag.WriteProperty(Entry, Value)
    ff = FreeFile
    Open sFile For Binary As #ff
        Put #ff, , propBag.Contents
    Close #ff

End Sub

Public Function readData(sFile As String, Entry As String, Optional def As Variant)
    Dim propBag     As New PropertyBag
    Dim varData     As Variant
    Dim b()         As Byte
    Dim ff          As Integer

    If Dir(sFile) <> vbNullString Then
        ff = FreeFile
        Open sFile For Binary As #ff
            Get #ff, , varData
        Close #ff
        b = varData
        propBag.Contents = b
        readData = propBag.ReadProperty(Entry, def)
    End If

End Function

Public Function readObject(sFile As String, Entry As String) As Object
    Dim propBag     As New PropertyBag
    Dim varData     As Variant
    Dim b()         As Byte
    Dim ff          As Integer

    If Dir(sFile) <> vbNullString Then
        ff = FreeFile
        Open sFile For Binary As #ff
            Get #ff, , varData
        Close #ff
        b = varData
        propBag.Contents = b
        Set readObject = propBag.ReadProperty(Entry)
    End If

End Function

i imas svoju bazu! :)

a funkcije koristis ovako:

Code:

'ovako upisujes sliku (ili text, broj, objekat...) u bazu:
Call WriteData("C:\test.data", "SomePicture", Picture1.Picture)
'ovako citas sliku (objekat) iz baze:
Picture1.Picture = readObject("C:\test.data", "somepicture")
'a text (broj, ili bilo sta sem objekta) citas ovako:
Text1.Text = ReadData("C:\test.data", "Test_Value042")

samo moras da vodis racuna da ti u Entry stringu nema ramaka i da pocinje sa slovom i da sme samo da sadrzi a-z,A-Z,0-9,_ (kao property neke kontrole...)

ovo nije los nacin da se odradi to sto ti treba, mada bi trebalo jednom da naucis da radis sa "pravim" bazama jer ce ti to kad tad zatrebati...

pozdrav

[ krp4 @ 02.08.2005. 01:39 ] @

E, HVALA PUNO!

[ Aleksandar Ružičić @ 02.08.2005. 03:05 ] @

np :)