Provjeri da li je module zapocet kao:

Public Function SetProperties(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer

ocito sa debuger ne moze da prepozna varPropValue jer najvjerovatnije nije deklarisan (kao u gornjem primjeru...)

Mislim da napočetku nisam rekao nešto vrlo važno.
Radi se o problemima u slučaju Access projekta.
Hajde ljudi da ovo pokušamo riješiti mislim da je interesantno za mnoge. Sve fino napravimo
a onda neko držrći Shift dođe direktno do tabela i upita...

Bila je dugacka rasprava o tome i jedan covek je uvek uspevao da razvali zastitu. prema tome, nema 100% sigurnog nacina da se Access zastiti od otvaranja pomocu SHIFT ENTER. Ako protiv sebe imate majstora, nista vam ne vredi. Ako imate prosecnog korisnika, najobicnije Hide Database window pomaze vecini slucajeva. Ili, jednostavno objasnite ljudima da nije u njihovom interesu da kopaju po bazi i nesto uniste. Ako imas korisnike koji zele da namerno ostete program, onda je problem mnogo veci nego zastita aplikacije an ovaj ili onaj nacin.

Ako iz cisto akademskih razloga zelis da proucis SHIFT ENTER, pocni odavde: http://www.mvps.org/access/general/gen0040.htm

:-)

Zidar, tvoja izjava je potpuno OK. Ali, ja u firmi imam "genijalce" koji vole
da glume hakere.
Iz takođe akademskih razloga, ponavljam da se radi o Access projektu
kod koga kod koga si mi naveo, i koga ja od prije znam, NE RADI....

Željko

Evo ti gotov kod koji treba staviti u modul. Obrati paznju na prvi red u kodu (onaj koji je removan) ni ova funkcija ne radi ako nisi ukljucio DAO 3.6
Probaj ovo pa mozes da ukljucis i iskljucis shift kad god pozelis.
Iskljucenje shifta ja obicno stavljam na neku sliku pa double click pa zovem funkciju allow Bypass.
.
'da bi radila ova funkcija mora biti omogucena referenca tools/references/Microsoft DAO 3.6 Object Library
Function PreventBypass() As Boolean
On Error GoTo errPreventBypass

CurrentDb.Properties("AllowBypassKey") = False

errPreventBypass:
If Err = 3270 Then
Set prp = CurrentDb.CreateProperty("AllowBypassKey", _
dbBoolean, False, True)
CurrentDb.Properties.Append prp
Set prp = Nothing
End If
End Function

Function AllowBypass() As Boolean
CurrentDb.Properties("AllowBypassKey") = True
End Function

JAVI KAKO JE PROSLO!

Prije zadnjeg odgovora sam našao sljedeci kod koji PROVJERENO RADI
i to u Access projektu, što je meni i trebalo, pošto varijantu sa bazom u mdb
imam od ranije (zahvaljujući svakako ovoj konferenciji):

Public Function AddCustomConnectionProperty(strPropName As String, varPropValue As Variant) As Boolean
' Add custom properties to the AccessObjectProperties
' collection that is associated with an AccessObject object.
Const conPropNotFoundError = 3265
On Error GoTo AddProp_Err

With CurrentProject
.Properties(strPropName) = varPropValue
End With
AddCustomConnectionProperty = True
AddProp_Bye:
Exit Function

AddProp_Err:
If Err = conPropNotFoundError Or Err = 2455 Then
With CurrentProject.Properties
.Add strPropName, varPropValue
End With
Resume
Else
MsgBox Err.Description
AddCustomConnectionProperty = False
Resume AddProp_Bye
End If

End Function

I use the following routine to completly secure my databases:

Public Function SecureDatabase()

AddCustomConnectionProperty "AllowBypassKey", False
AddCustomConnectionProperty "AllowBreakIntoCode", False
AddCustomConnectionProperty "StartupShowDBWindow", False
AddCustomConnectionProperty "StartupShowStatusBar", True
AddCustomConnectionProperty "AllowBuiltinToolbars", False
AddCustomConnectionProperty "AllowShortcutMenus", False
AddCustomConnectionProperty "AllowBuiltInToolbars", False
AddCustomConnectionProperty "AllowFullMenus", False
AddCustomConnectionProperty "AllowToolbarChanges", False
AddCustomConnectionProperty "AllowSpecialKeys", False

End Function

Treba napraviti skriveno dugme sa šifrom da možemo po potrebi aktivirati Shift key
kada je to nama potrebno (da ne zalupimo vrata za sobom a ključ da ostane unutra...)

Željko

Molim te da poslednju poruku dodas na temu 'Baza znanja'

Hvala na trudu

Molim te Zeljko objasni kako konrektno implementiras ovaj kod u access bazi pritiskom na skriveni taster?

pozdrav nexi

Ide odgovor sa danom zakašnjenja, bio sam na putu...
Na uvodnu formu svog programa postaviš dugme za koga je Transparent Yes (čisto da se ne vidi da ne bi iritiralo korisnike) i koje se zove recimo bIskljuciShift.
U On Click događaj stavi sljedeće:

Private Sub bIskljuciShift_Click()
On Error GoTo Err_bIskljuciShift_Click

Dim strInput As String
Dim strMsg As String
Beep
strMsg = "Zelite li omoguciti SHIFT key?" & vbCrLf & vbLf & _
"Molimo Vas upisite sifru za omogucivanje SHIFT key-a."
strInput = InputBox(Prompt:=strMsg, Title:="Shift key nije omogucen")
If strInput = "3232" Then

AddCustomConnectionProperty "AllowBypassKey", True
AddCustomConnectionProperty "AllowBreakIntoCode", True
AddCustomConnectionProperty "StartupShowDBWindow", True
AddCustomConnectionProperty "StartupShowStatusBar", True
AddCustomConnectionProperty "AllowBuiltinToolbars", True
AddCustomConnectionProperty "AllowShortcutMenus", True
AddCustomConnectionProperty "AllowBuiltInToolbars", True
AddCustomConnectionProperty "AllowFullMenus", True
AddCustomConnectionProperty "AllowToolbarChanges", True
AddCustomConnectionProperty "AllowSpecialKeys", True

MsgBox "Shift key je ukljucen." & vbCrLf & vbLf & _
"Slijedeci put kad budete otvarali vasu bazu Shift key ce biti omogucen.", _
vbInformation, "Set Startup Properties"
Else
Beep

AddCustomConnectionProperty "AllowBypassKey", False
AddCustomConnectionProperty "AllowBreakIntoCode", False
AddCustomConnectionProperty "StartupShowDBWindow", False
AddCustomConnectionProperty "StartupShowStatusBar", True
AddCustomConnectionProperty "AllowBuiltinToolbars", False
AddCustomConnectionProperty "AllowShortcutMenus", False
AddCustomConnectionProperty "AllowBuiltInToolbars", False
AddCustomConnectionProperty "AllowFullMenus", False
AddCustomConnectionProperty "AllowToolbarChanges", False
AddCustomConnectionProperty "AllowSpecialKeys", False

MsgBox "Sifra nije prihvacena!" & vbCrLf & vbLf & _
"Shift key je onemogucen." & vbCrLf & vbLf & _
"Slijedeci put kad budete otvarali bazu Shift key ce biti onemogucen.", _
vbCritical, "Netacna sifra"
Exit Sub
End If

Exit_bIskljuciShift_Click:
Exit Sub

Err_bIskljuciShift_Click:
MsgBox "bIskljuciShift_Click", err.Number, err.Description
Resume Exit_bIskljuciShift_Click
End Sub

U module neka bude modul koji se recimo zove Shift (čisto zbog preglednosti) i u kome je:

Public Function AddCustomConnectionProperty(strPropName As String, varPropValue As Variant) As Boolean
' Add custom properties to the AccessObjectProperties
' collection that is associated with an AccessObject object.
Const conPropNotFoundError = 3265
On Error GoTo AddProp_Err

With CurrentProject
.Properties(strPropName) = varPropValue
End With
AddCustomConnectionProperty = True
AddProp_Bye:
Exit Function

AddProp_Err:
If err = conPropNotFoundError Or err = 2455 Then
With CurrentProject.Properties
.Add strPropName, varPropValue
End With
Resume
Else
MsgBox err.Description
AddCustomConnectionProperty = False
Resume AddProp_Bye
End If

End Function

Probaj pa javi dali je OK. Meni radi baš kako treba.

Pozdrav Željko

U bazu probni primer (bez ikakvih dodatnih podesavanja) postavio sam dugme sa kodom i modul shift. dugme prikazuje odgovarajuce poruke, ali kada sam pokusao ponovo da udjem u bazu sve je bilo dostupno i shift. Izgleda da treba jos nesto podesiti.
Hvala Zeljko sto si se javio.

Pozdrav Nesa

Ne mogu vjerovati!!
Krenuo sam od početka, napravio potpuno novi projekat dodao jednu formu sa jednim dugmetom koji pokreće proceduru, dodao modul Shift i SVE radi kako sam rekao.
Kada te upita za password a želiš da onemogućiš Shift nemoj otkucati ništa i pri sljedećem ulasku u projekt shift ne radi.
Šifra za ponovno aktiviranje Shift-a je 3232.
Stvarno ne treba ništa više podešavati i nemam nikakvog asa u rukavu.
Pazi forma sa dugmetom mora da se automatski podiže pri ulasku u projekt (dodaj je u Startup)

Pozdrav Željko

Lepo si rekao u projektu, nego ja nisam obratio paznju. Stvarno u projektu radi
jos jednom hvala Zeljko
pozdrav Nesa

Postavio sam ovo dugme na glavnu formu i napravio Shift modul ali i Shift-key je i dalje omogucen. Pritiskom na dugme bIskljuciShift izlazi poruka za sifru (3232) i kada unesem pogresno ili ne unesem nista javi se poruka da je shift-key onemogucen, ali u stvari nije, tj. moze se uci sa shift+enter. Sta sam propustio?

Ovo radi samo u Access-u projektu. Da li je to u pitanju.

Zeljko

Aplikaciju sam radio u Accessu