snimanje textbox u txt

[ Aleksandar Vasic @ 03.11.2007. 14:34 ] @

Ovako, imam 75 Textbox-ova i sve njih treba da zapamtim u jedan txt fajl,da bi kasnije taj fajl ucitao i da se u svakom textbox-u pojavi ono sto je pre toga zapamceno....Znaci ako ima 2 textbox-a u prvom tekst "a" a u drugom "b",da mi kad ucitam opet bude tako,da se ne pomeshaju....Ja sam to radio na jedan nacin,da svakom tekstobox-u dodelim po jednu promenljivu,ali ima ih mnogo.......Da li moze nekako krace da se zapamti svih 75 textbox-ova.........

[ Shadowed @ 03.11.2007. 14:56 ] @

Imas razne nacine..
Mozes svaki textbox u zaseban fajl.
Mozes, ukoliko imas neki string koji si siguran da ti se nece pojaviti ni u jednom od nih, da razdvojis tekstove tim stringom u jednom fajlu.
A mozes da upises prvo duzinu prvog, pa onda tekst iz prvog, pa duzinu drugog pa njegov tekst. Onda kada citas prvo procitas duzinu i znas koliko da citas za prvi pa tako dalje za ostale.

Mozes i... ok, ovo ne smem da kazem, proterace me sa foruma ;p

[ Aleksandar Vasic @ 03.11.2007. 15:08 ] @

Snimanje

Code:
Private Sub Command1_Click()
On Error Resume Next
Open "c:\test.txt" For Output As #1
Print #1, Text1.Text
Print #1, Text2.Text
Close #1
End Sub

Ucitavanje

Code:
Private Sub Form_Load()
Dim a, s As String
On Error Resume Next
Open "c:\test.txt" For Input As #1
Input #1, a
Input #1, s
Close #1

Text1.Text = a
Text2.Text = s
End Sub

Ja sam to radio ovako,ali mi je mnogo da kada ucitavam,da toliko stringova dodelim,jer mi za svaki textbox treba po jedan string....

[ Shadowed @ 03.11.2007. 20:01 ] @

Sto ne bi umesto:
Input #1, a
Text1.Text = a

stavio
Input #1, Text1.Text

?

PS. ako lupim nesto, ne zamerite, radio sam samo sa fso...

[ Aleksandar Vasic @ 03.11.2007. 20:13 ] @

eeeeeeeeee vidis to mi nije palo na pamet......zahvaljujem ;)

[ Aleksandar Vasic @ 03.11.2007. 21:59 ] @

e ne moze tako......mora promenljiva :D
nije bitno,reshio sam to...........javlja mi se dugi problem......npr ako zapamtim datum,nece da mi ucita.......ako je datum 00.00.00 onda kada se ucita ispishe ga kao 0,00 el moze nekako to da se sredi..... :D

[ Aleksandar Ružičić @ 03.11.2007. 22:08 ] @

pokusaj da umesto Print koristis Write

Citat:

Shadowed: ... Mozes i... ok, ovo ne smem da kazem, proterace me sa foruma ;p

U pravu si, bolje cuti :) da nam ne odes kao rajko :D

[ Aleksandar Vasic @ 03.11.2007. 22:20 ] @

hvala krcko,radi ;)

[ BinLaden @ 04.11.2007. 15:14 ] @

Vec sto puta je na ovom forumu govoreno da kada koristis mnogo istih
objekata napravis NIZ OBJEKATA a evo kako bi to u tom tvom slucaju izgledalo.
Umjesto sto si postavio 75 tekstboxova koji se zovu Text1, Text2,.... Text75
napravi niz kontrola textboxsova na sledeci nacin.
Postavi na formu jedan text box. Sad klikni desnom tipkom misa na taj
textboks i odaberi "Copy". Klikni negdje na formu desnom tipkom i odaberi "Paste".
VB ce izbaciti poruku "dali zelis da napravis niz kontrola" i ti klikni na "Yes".
Sad jos 73 puta klikni na "Paste" ili na tastaturi "Ctrl + V" i naprvices 75 textboksova
koji se svi zovu "Text1" ali im se "Index" razlikuje od 0 do 74.

A evo zbog cega je to korisno u ovom tvom slucaju.
Snimanje

Code:
Private Sub Command1_Click()
Dim I As Long
On Error Resume Next
Open "c:\test.txt" For Output As #1

For I = 0 To 74
Write #1, Text1(I).Text
Next I

Close #1
End Sub

Ucitavanje

Code:
Private Sub Form_Load()
Dim s As String, I As Long
On Error Resume Next
Open "c:\test.txt" For Input As #1
For I = 0 To 74
Input #1, s
Text1(I).Text = s
Next I

Close #1

End Sub

Sad pogledaj koliko redova koda ima u ovom gore rjesenju a pogledaj koliko si ti napisao
koristeci svoj nacin.
Jos nesto sto sam zapazio: Kada deklarises promjenjive u jednom redu kao sto si ti
Dim a, s As String, samo ti je "s" promjenjiva tipa string a promjenjiva "a" je Variant.
Znaci za svaku promjenjivu moras da definises tip a ne samo na kraju reda:
Dim a As String, s As String.

_{[Ovu poruku je menjao BinLaden dana 04.11.2007. u 16:24 GMT+1]}

[ Aleksandar Vasic @ 04.11.2007. 15:36 ] @

hvala