ListView kako ubaciti podatke u bazu

[ KaAmIkAzA @ 28.08.2008. 13:20 ] @

Pozdrav svima.

Problem je sledeci:
ListView popunjavam iz forme i npr. u njega stavim oko 10 redova, kako odraditi kada snimam da mi u bazu stavi 10 rekorda odjednom.

[ goranvuc @ 30.08.2008. 00:40 ] @

Za pocetak:

- Koja baza
- ADO, DAO ili nesto trece
- Koja ti je struktura tabele u bazi, koje polje je primarni kljuc (ako ga ima)
- Sta ti ti znaci odjednom - u jednoj SQL naredbi ili da se svih 10 dodaju u istoj proceduri

Dakle, probaj da nam pomognes da bi ti pomogli.

[ KaAmIkAzA @ 30.08.2008. 11:02 ] @

@goranvuc

Ovako baza je Access, koristim ADO, tabela mi je tblServisiVozila u njoj imam polja

-RedniBroj - AutoNumber - primarni kljuc
-SifraVozila - number
-SifraServisa - number

U formi ServisiVozila imam:

txtSifraVozila
lstServisi
lstServisiUradeni

Prilikom otvaranja forme popunjava mi se lstServisi, sa mogucim servisima iz baze, u toj listi odaberem npr. nekih pet servisa i oni se prebace u lstServisiUradeni, e sada mi treba kada idem na cmdSnimi da mi u tabelu tblServisiVozila snimi za to vozilo tih 5 servisa.

Valjda sam bio iole blizu objasnjenja.

[ goranvuc @ 30.08.2008. 11:12 ] @

Jasno mi je sve, pomoci cu ti oko procedure, ali bih te molio da uploadujes bar formu na kojoj su ti nacrtane sve te kontrole uz kod koji puni te listview-ove (ne znam za ostale ovde, ali meni je stvarno dosta crtkanja i podesavanja kontrola na formama).

Dakle, salji to i resavamo odmah, tj. ako posaljes u narednih x minuta dok sam na forumu.

[ KaAmIkAzA @ 30.08.2008. 12:04 ] @

OK evo izdvojio sam

[ goranvuc @ 30.08.2008. 13:43 ] @

OK, evo ti kod, nema previse komentara i error handlinga, to ostaje na tebi. Inace, malo si to konfuzno postavio, ali sam ispostovao tvoju postavku (koliko god da mi nije bliska)

Code:

'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
'!Zahvaljujem kvakaru, tj. bravaru 22 sto me je naterao da stalno pisem ovo!
'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

'****************************************************************
'*     Author : Goran Vucicevic MCP ([email protected])        *
'*        URL : www.clickersoftware.com                          *
'*  Copyright (c) Goran Vucicevic.  All rights reserved          *
'*    Company : Clicker Agencija    (www.clickersoftware.com)    *
'*       Date : Subota 30 Avgust 2008                            *
'*****************************************************************

' *** LICENSE AGREEMENT ***
' Morate traziti dozvolu autora da bi koristili ovaj kod u komercijalne svrhe
' Ovaj kod se moze koristiti slobodno u nekomercijalne svrhe,
' ali se mora navesti ime autora

Option Explicit

Public bNoviUlaz As Boolean
Public sRegOznaka As String

Private Sub cmdIzbaci_Click()
   Dim currItem As ListItem

   If lstServisiUradeni.SelectedItem Is Nothing Then
      MsgBox "Niste odabrali nijedan servis!", vbCritical, "Greska"
      Exit Sub
   End If

   'Prenos stavke
   Set currItem = lstServisi.ListItems.Add(, lstServisiUradeni.SelectedItem.Key, lstServisi.SelectedItem.Text, 1, 1)
   currItem.SubItems(1) = lstServisiUradeni.SelectedItem.SubItems(1)
   currItem.SubItems(2) = lstServisiUradeni.SelectedItem.SubItems(2)

   'Uklanjanje
   lstServisiUradeni.ListItems.Remove lstServisiUradeni.SelectedItem.Index

End Sub
Private Sub cmdIzlaz_Click()

   Unload Me

End Sub
Private Sub cmdSnimi_Click()
   Dim rstServisi As New adodb.Recordset
   Dim currItem As ListItem

   If lstServisiUradeni.ListItems.Count = 0 Then
      Unload Me
      Exit Sub
   End If

   rstServisi.Open "SELECT * FROM tblServisiUradeno", CN, adOpenKeyset, adLockOptimistic, adCmdText

   For Each currItem In lstServisiUradeni.ListItems
      rstServisi.AddNew
      rstServisi("SifraVozila") = txtRegOznaka.Text
      rstServisi("SifraServisa") = CLng(Replace(currItem.Key, "K", ""))
      rstServisi.Update
   Next

   rstServisi.Close
   Set rstServisi = Nothing

   Unload Me

End Sub
Private Sub cmdUbaci_Click()
   Dim currItem As ListItem

   If lstServisi.SelectedItem Is Nothing Then
      MsgBox "Niste odabrali nijedan servis!", vbCritical, "Greska"
      Exit Sub
   End If

   'Prenos stavke
   Set currItem = lstServisiUradeni.ListItems.Add(, lstServisi.SelectedItem.Key, lstServisi.SelectedItem.Text)
   currItem.SubItems(1) = lstServisi.SelectedItem.SubItems(1)
   currItem.SubItems(2) = lstServisi.SelectedItem.SubItems(2)

   'Uklanjanje
   lstServisi.ListItems.Remove lstServisi.SelectedItem.Index

End Sub
Private Sub Form_Load()

   txtRegOznaka.Text = sRegOznaka
   Popunjavanje_lstServisi

End Sub

'Popunjavanje liste servisa
Private Sub Popunjavanje_lstServisi()
   Dim rstServisi As New adodb.Recordset
   Dim currItem As ListItem

   'Ciscenje kolekcije listitems
   lstServisi.ListItems.Clear

   'Otvaranje rekordset-a
   rstServisi.Open "SELECT * FROM tblServisi ORDER BY NazivServisa", CN, adOpenStatic, adLockReadOnly, adCmdText

   'Dodavanje servisa u petlji, kao kljuc se koristi "K" & rstServisi("RedniBroj") jer Key ne sme biti broj
   Do While Not rstServisi.EOF

      Set currItem = lstServisi.ListItems.Add(, "K" & rstServisi("RedniBroj"), lstServisi.ListItems.Count + 1, 1, 1)
      currItem.SubItems(1) = rstServisi("RedniBroj")
      currItem.SubItems(2) = rstServisi("NazivServisa") & ""

      rstServisi.MoveNext

   Loop

   'Zatvaranje rekordseta
   rstServisi.Close
   Set rstServisi = Nothing

End Sub

U prilogu ti je i forma, jedino sto sam menjao je da sam dodao jos jednu kolonu na listu uradjenih servisa.

[ KaAmIkAzA @ 30.08.2008. 13:54 ] @

@goranvuc

Hvala ti puno, to je to. HVALA JOS JEDNOM

[ stefanpn @ 01.09.2008. 13:04 ] @

LOL!

Samo iz polja u tabeli sam zakljucio da program "nije" komercijalan... :)

I jos jedan LOL sto ce te nase mlade nade ispostovati za ovo: "ali se mora navesti ime autora".

[ goranvuc @ 01.09.2008. 15:51 ] @

Pa posto me je ovde neki idiot optuzivao da sam ukrao svoj kod od samog sebe, moram ubuduce ovako. Taj komentar ce biti uz svaki ozbiljniji deo koda koji postavim.