[ BrackoNe @ 04.02.2011. 16:23 ] @
Code:

-----------------------------------------------
Reoni
-----------------------------------------------
Sever | Beograd |  Centar   | Zapad | Istok | Jug
------|---------|----------|-------|-------|---
Stp    | Kotež    | Svilajnac | Lazar. | Smed.| Niš
------|---------|----------|-------|-------|---
NS     | Avala    | Jagodina  | Topola| Bože. | Svrljig
------|---------|----------|-------|-------|---
Ruma


Ova tabela mi je imenovana Reon.

Sada imam u drugoj grupnoj tabeli nasumično postavljene gradove, a treba mi da iz zaglavlja izvuče koji je to reon.

Da li može kada napišem Stp, da mi u koloni pored odmah ispiše Sever. Kada piše Niš, da u koloni pored piše Jug.

Kako to da uradim?

Hvala unapred,
Nemanja
[ BrackoNe @ 04.02.2011. 16:26 ] @
Pokušavam sa Hlookup, i kontam da tako treba, ali ne znam gde grešim?

Code:
=HLOOKUP(L21;Reon;2;FALSE)


L21 - kolona u kojoj mi je tekst sa kojim upoređujem
Reon - tabela u kojoj se traži tekst
2 - u drugom mi je redu tekst koji tražim (Sever, Beograd...)
False - Tražim tačno to.
[ Ivek33 @ 04.02.2011. 19:32 ] @
Citat:
BrackoNe:Da li može kada napišem Stp, da mi u koloni pored odmah ispiše Sever. Kada piše Niš, da u koloni pored piše Jug.
Ako sam te dobro razumio evo jedan od primjera, iako bilo bi bolje da si postavio fajl u attachu

Ja sam pokušao na drugačiji način, pa ako ti odgovara

- Range "reon" je u rasponu A1:F3

- u ćeliji A5, A6, A7 (tvoja L21...) tražiš Stp, NS....

- u B5 je međurezultat koji vraća broj stupca a matrična formula glasi
=IF(A5>0;MAX(IF(reon=A5;COLUMN(A2:F3);0));"") završavaš je sa Ctrl+Shift+Enter

- u C5 je formula koja vraća naziv iz stupca za traženi pojam
=IF(ISNUMBER(B5);INDIRECT("R1C" &B5;FALSE);"")
[ Jpeca @ 04.02.2011. 19:49 ] @
HLOOKUP funkcija (slično kao VLOOKUP) gleda prvi red u zadatom opsegu i na osnovu toga vraća podatak iz odgovarajuće kolone. To nije ono što tebi treba.

Ukoliko su ti vrednosti u oblasti koju pretražuješ jedinstvene da pronađeš broj kolone u kojoj se tražena vrednost nalazi možeš na više načina, a jedan način je pomoću funkcije SUMPRODUCT koja radi sa nizovima (ili pomoću matričnih formula kao što je Ivek33 predložio).

Ako je Oblast koju pretražuješ Reon A1:F5 a H1 vrednost koju tražiš formula bi bila
Code:
SUMPRODUCT((A2:F5=H1)*COLUMN(A2:F5))


Ona vraća broj kolone u kojoj pronadjena vrednost iz H1. (Primeti da je prvi red, zaglavlje, izostavljeno iz pretraživanja). Neka je pronađena kolona k

Sada da vratiš odgovarajući natpis iz zaglavlja za tu kolonu možeš koristiti OFFSET. Ova funkcija vraća vrednost ćelije koja je r redova i k kolona udaljena od neke početne ćelije. Ako je početna ćelija za tvoj opseg A1
=OFFSET(A1, 0, k-1) vratiće natipis iz prvog reda k-te kolone. Kad iskombinujemo ove dve formule dobijamo

Code:
=OFFSET(A1; 0; SUMPRODUCT((A2:F5=H1)*COLUMN(A2:F5))-1)
[ BrackoNe @ 04.02.2011. 19:54 ] @
Hvala veliko obojici, to je ono šta mi je trebalo!

Isprobaću i Jpeco tvoje, čini mi se kraće, ali sam video da vraća brojne vrednosti. Moram malo da se vratim u igru, dugo nisam.
Pozaboravljao sam traganje i parsiranje, a bukvalno samo to mi treba u Excelu i sve rešavam. :)

Hvala veliko još jednom!
[ Ivek33 @ 04.02.2011. 21:27 ] @
Radi drugih čitalaca teme,
vidjevši ovo @JPecino rješenje sada tek uočih da bi i moje moglo ići bez međurezultata (broja za stupce)

tada bi matrična formula u B5 (u mom primjeru) bila

=INDIRECT("R1C"&MAX(IF(reon=A5;COLUMN(reon);0));FALSE)
(završena sa Ctrl+Shift+Enter)
[ Brodoplovac @ 05.02.2011. 22:56 ] @
=INDIRECT("r1c1";FALSE)
=INDIRECT("A1";TRUE)

Nisam imao pojma da postoji i ovaj zapis "row1, column1" tj."r1c1". Sav sam se izgubio kad sam ovo video. Gornja dva zapisa su znači ista.