Neka skripta koja bi izvestavala ko je konektovan preko pppoe

[ MilosOskar @ 22.01.2012. 23:18 ] @

Kao sto pise u naslovu poruke.

Znaci treba mi skripta koja ce mi slati na mail ko je u tom trenutku konektovan na mrezu putem pppoe konekcije...

Da li neko ima ideju gde mogu da nadjem ili da li neko moze da je napise ili je mozda vec ima ?

Pozdrav

[ BigFoot @ 23.01.2012. 11:31 ] @

Citat:

MilosOskar: Kao sto pise u naslovu poruke.

Šta piše u naslovu poruke?

Citat:

MilosOskar:Znaci treba mi skripta koja ce mi slati na mail ko je u tom trenutku konektovan na mrezu putem pppoe konekcije...

To ti je bolje preko SMS. Ako već imaš mogućnost da skineš mail, možeš i direktno da gledaš i odmah primetiš kako se ko nakači i otkači.

[ MilosOskar @ 23.01.2012. 11:43 ] @

Citat:

BigFoot: To ti je bolje preko SMS. Ako već imaš mogućnost da skineš mail, možeš i direktno da gledaš i odmah primetiš kako se ko nakači i otkači.

Kako to da realizujem? Kako da dobijam obavestenja putem sms-a za pppoe ?

[ nino1987 @ 23.01.2012. 12:42 ] @

http://wiki.mikrotik.com/wiki/Manual:Tools/Sms
http://wiki.mikrotik.com/wiki/Monitoring_Network_thru_SMS_Alerts

[ MilosOskar @ 23.01.2012. 13:05 ] @

Hvala nino!

[ Aleksandar Đokić @ 24.01.2012. 03:46 ] @

imas onu skriptu sto sakuplja sve iz /interface wireless registration-table, stavi da sakupi sve iz ppp active i u "for each" stavi jedan if koji ce ako je "name" to i to poslati mail,

probaj jednom sam, ukapiraces za sat dva i onda ce ti biti lako bilo sta da napises

[ Aleksandar Đokić @ 26.01.2012. 00:46 ] @

evo nesto sam prckao pa reko da ti sklopim na brzaka, ovako:

Code:

:local ime;

:foreach i in=[ /ppp active find] do={

:set ime [ppp active get $i name];

:if ($ime="stavi_ppp_ime") do={

:log info $ime;

};
};

ovde je valjda sve jasno, definises promenljivu "ime", vadis sva imena iz "ppp active" i uporedjujes sa navedenim, ukoliko postoji radis nesto...

posto nisam hteo sve da ti napisem stavio sam samo da printa u log ako pronadje navedeno ime medju aktivnim ppp konekcijama, ti trebas umesto

:log info $ime;

da stavis ono :tool e-mail send... ili /tool e-mail send...

[ MilosOskar @ 26.01.2012. 14:52 ] @

Code:
:local ime;

:foreach i in=[ /ppp active find] do={

:set ime [ppp active get $i name];

:if ($ime="OVDE PPP NAME OD KORISNIKA") do={

tool e-mail send to="MOJA MAIL ADRESA" subject="NEKI SUBJECT"

};
};

Jel ovako ok?

Samo još da pitam, ova skripta kada pronađe zadato ppp ime u Active Connections, tada mi pošalje mail ?

Hvala na izdvojenom vremenu!

[ Aleksandar Đokić @ 27.01.2012. 00:26 ] @

haha kako li sam te ja razumeo da treba da salje mail ako pronadje odgovarajucu ppp konekciju... tebi u stvari treba lista svih ppp na mail...sad cemo da ispravimo :)

Code:

:local ime;
:local calID;
:local vreme;

:global sadrzaj;

:set sadrzaj;

:foreach i in=[ /ppp active find] do={

:set ime [ppp active get $i name];

:set calID [ppp active get $i caller-id];

:set vreme [ppp active get $i uptime];

:set sadrzaj "$sadrzaj PPP: $ime, MAC: $calID, UPTIME: $vreme \n";
};

/tool e-mail send [email protected] subject=aktive_konekcije body="$sadrzaj";

eto, samo iskopiraj,

ako ti treba jos nesto iz ppp konekcije osim ovog, dodaj promenljivu, preko "set" izvadi i dodaj u "sadrzaj", mozes da izvuces sve sto vidis u winboxu i preko terminala

[ MilosOskar @ 27.01.2012. 13:58 ] @

Ovog trenutka iskopirao, malčice samo prepravio i testirao!

Radi kao sat!! :))

guslac hvala ti puno na pomoći!

E sada ako se nisi smorio i ako si raspoložen mogao bi mi pomoći da ovu skriptu sada i onu što si mi ranije pomogao (za registration table, šalje mi na mail ko je nakačen, sa kojim signalom, koliko dugo i tx/rx rate...) spojimo u jednu. Da mi ne bi slao previše mailova dnevno, ovaj za ovo onaj za ono...nego lepo sve u jednom!

Evo one skripte od ranije:

Code:
:local signal;
:local ime;
:local brzinatx;
:local brzinarx;
:local vreme;
:local macadresa;
:global sadrzaj;

:set sadrzaj;

:foreach i in=[ /interface wireless registration-table find ap=no] do={

:set signal [interface wireless registration-table get $i signal-strength];

:set ime [interface wireless registration-table get $i comment];

:set brzinatx [interface wireless registration-table get $i tx-rate];

:set brzinarx [interface wireless registration-table get $i rx-rate];

:set macadresa [interface wireless registration-table get $i mac-address];

:set vreme [interface wireless registration-table get $i uptime];

:set sadrzaj "$sadrzaj ***KORISNIK*** $ime Mac adresa: $macadresa Signal: $signal Tx rate: $brzinatx Rx rate: $brzinarx Konektovan: $vreme \n";

};

tool e-mail send to="moj mail" subject="Izvestaj" body="

$sadrzaj"

A evo i ove nove sa vrlo malim prepravkama:

Code:
:local ime;
:local calID;
:local vreme;

:global sadrzaj;

:set sadrzaj;

:foreach i in=[ /ppp active find] do={

:set ime [ppp active get $i name];

:set calID [ppp active get $i caller-id];

:set vreme [ppp active get $i uptime];

:set sadrzaj "$sadrzaj ***KORISNIK*** $ime, Mac adresa: $calID, Konektovan: $vreme \n";
};

/tool e-mail send to="moj mail" subject="PPP Izveštaj" body="$sadrzaj";

E to bi bilo to. Znači treba bi mi pomoć da ove dve spojimo u jednu.

Još nešto samo, da li je moguće u skripti napisati neku komandu da recimo neki deo bude boldiran kada mi stigne na mail (nešto možda poput <b> ... </B> ) ??

Srdačan pozdrav!

[ Aleksandar Đokić @ 27.01.2012. 21:38 ] @

pa samo dodaj...

Code:

:local signal;
:local ime;
:local brzinatx;
:local brzinarx;
:local vreme;
:local macadresa;
:global sadrzaj;

:set sadrzaj;

:foreach i in=[ /interface wireless registration-table find ap=no] do={

:set signal [interface wireless registration-table get $i signal-strength];

:set ime [interface wireless registration-table get $i comment];

:set brzinatx [interface wireless registration-table get $i tx-rate];

:set brzinarx [interface wireless registration-table get $i rx-rate];

:set macadresa [interface wireless registration-table get $i mac-address];

:set vreme [interface wireless registration-table get $i uptime];

:set sadrzaj "$sadrzaj ***KORISNIK*** $ime Mac adresa: $macadresa Signal: $signal Tx rate: $brzinatx Rx rate: $brzinarx Konektovan: $vreme \n";

};

:foreach i in=[ /ppp active find] do={

:set ime [ppp active get $i name];

:set calID [ppp active get $i caller-id];

:set vreme [ppp active get $i uptime];

:set sadrzaj "$sadrzaj ***KORISNIK*** $ime, Mac adresa: $calID, Konektovan: $vreme \n";
};

/tool e-mail send to="moj mail" subject="Izvestaj" body="$sadrzaj"

nisam bas siguran, probaj pa javi...

[ Aleksandar Đokić @ 27.01.2012. 21:39 ] @

pa samo dodaj...

Code:

:local signal;
:local ime;
:local brzinatx;
:local brzinarx;
:local vreme;
:local macadresa;
:local ime2;
:local calID;
:local vreme2;

:global sadrzaj;

:set sadrzaj;

:set sadrzaj "$sadrzaj -------------WIRELESS----------- \n";

:foreach i in=[ /interface wireless registration-table find ap=no] do={

:set signal [interface wireless registration-table get $i signal-strength];

:set ime [interface wireless registration-table get $i comment];

:set brzinatx [interface wireless registration-table get $i tx-rate];

:set brzinarx [interface wireless registration-table get $i rx-rate];

:set macadresa [interface wireless registration-table get $i mac-address];

:set vreme [interface wireless registration-table get $i uptime];

:set sadrzaj "$sadrzaj ***KORISNIK*** $ime Mac adresa: $macadresa Signal: $signal Tx rate: $brzinatx Rx rate: $brzinarx Konektovan: $vreme \n";

};

:set sadrzaj "$sadrzaj \n";

:set sadrzaj "$sadrzaj -------------PPP INFO----------- \n";

:foreach i in=[ /ppp active find] do={

:set ime2 [ppp active get $i name];

:set calID [ppp active get $i caller-id];

:set vreme2 [ppp active get $i uptime];

:set sadrzaj "$sadrzaj ***KORISNIK*** $ime2, Mac adresa: $calID, Konektovan: $vreme2 \n";
};

/tool e-mail send to="mail" subject="Izvestaj" body="$sadrzaj"

nisam bas siguran, probaj pa javi...

[ MilosOskar @ 29.01.2012. 21:29 ] @

Prekopirao, dodao mail i isprobao.

Radi odlično! :))

guslac hvala puno na nesebično pruženoj pomoći!

Jel postoji mogućnost da deo skripte poput ***korisnik*** bude boldiran kada stigne na mail? Ili ako može još bolje da sam ispred toga postavlja 1. 2. 3. i tako redom, da ne bih morao da brojim koliko njih je konektovano.

Ako preterujem, upozorite me! :)

Pozdrav

[ Aleksandar Đokić @ 30.01.2012. 06:19 ] @

1. tu bi ti trebala podrska za slanje html body u mailu, mislim da to tik nema

2. ako budem imao vremena pokusacu nesto, treba ti neka promenljiva koja ce se u svakoj iteraciji povecavati za jedan,

[ BigFoot @ 30.01.2012. 12:28 ] @

Iz MikroTik-a to neće moći, ali može XML koji bi se posle prikazivao na željeni način. Kako si zamislio i kad da okidaš ovu skriptu?

[ MilosOskar @ 31.01.2012. 12:32 ] @

@guslac: ok, ako uhvatis vremena pokusaj pa javi.
@bigfoot: aj pojasni malo to oko xml-a, jel moze to sa tika...?
Skriptu run-ujem cesto na oba tika, na svaka 3 sata. To je zato sto radim neku analizu nakacenosti svakog korisnika posebno, a nemam vremena da sedim po ceo dan za winboxom...

[ BigFoot @ 31.01.2012. 15:32 ] @

Citat:

BigFoot: Iz MikroTik-a to neće moći, ali može XML

Evo primera kako bi rezultujući XML mogao da izgleda:

Code:
<?xml version="1.0" encoding="utf-8"?>
<konekcije>
    <korisnik ime="MilosOskar">
        <signal>-66</signal>
        <brzinatx>560</brzinatx>
        <brzinarx>120</brzinarx>
        <mac>00:00:00:00:00:00</mac>
        <vreme>1d 12:05:30</vreme>
    </korisnik>
    <korisnik ime="Drugi korisnik">
        <signal>-71</signal>
        <brzinatx>730</brzinatx>
        <brzinarx>96</brzinarx>
        <mac>00:00:00:00:00:00</mac>
        <vreme>03:32:05</vreme>
    </korisnik>
</konekcije>

Ovo može da se ispiše iz MT i pošalje e-mailom. Posle praviš pregled sa izborom atributa koje prikazuješ i šareniš ih po želji

Umesto svih ovih gimnastika, uzmi RADIUS i imaćeš sve i broj konekcija i vreme i prenete količine podataka i preglede...

[ MilosOskar @ 31.01.2012. 16:03 ] @

Taj rezultujući XML izgleda zanimljivo!

Citat:

Umesto svih ovih gimnastika, uzmi RADIUS i imaćeš sve i broj konekcija i vreme i prenete količine podataka i preglede...

Jel bih morao poseban komp za to da podesim ili može da se digne i na Mikrotiku ?

Pozz

[ BigFoot @ 31.01.2012. 18:52 ] @

Za RADIUS poseban, User Manager na MikroTik-u.

P.S. Koristiš li Google ili neki drugi pretraživač?