Code:
Private Sub Combo6_AfterUpdate()

Dim rs As Object

Set rs = Me.Recordset.Clone
rs.FindFirst "[Naziv] = " & Str(Me![Combo6])
Me.Bookmark = rs.Bookmark
Naziv.SetFocus
Combo6.Value = ""

End Sub

Code:
FORMS
- Kako upotrebiti Combo Box da se forma pozicionira na trazeni rekord

Upozorenje: U Access 97 iranijim verzijama ovo moze da izazove bookmark bug .
Vidi site http://members.iinet.net.au/~allenbrowne/BugBookmark.html
Ako dobijete Error u Accessu 2000 ili 2002, moguce je da imate probleme sa Referencama. Vidi site:http://members.iinet.net.au/~allenbrowne/ser-38.html

Jedan od nacina za kretanje kroz bazu podataka jeste upotreba combo boxa za pretrazivanje. Combo box mora biti unbound (nije vezan za polja u forminom record source). Ideja je da korisnik izbere nesto iz padajuce liste i da onda Access prikaze u formi taj slog (record).

Pretpostavimo da je record source za formu tabela "tblCustomers" sa sledecom strukturom:

CustomerID Text (indexed as Primary Key).
Company Text
ContactPerson Text

Forma prikazuje podatke kao Single Form. Dodajte combo box u zaglavlje forme (Forms Header) i neka conbo box ima sledece properties:

Name cboMoveTo
Control Source [ostvite ovo prazno!]
Row Source Type Table/Query
Row Source tblCustomers
Column Count 3
Column Widths 0.6 in; 1.2 in; 1.2 in
Bound Column 1
List Width 3.5 in
Limit to List Yes

Zapazite da je Control Source za Combo box PRAZAN. Row source jeste ono sto se vidi u padajucoj listi.

Ovo je kod na AfterUpdate za Combo Box:

Sub CboMoveTo_AfterUpdate ()
Dim rs As DAO.Recordset

If Not IsNull(Me!cboMoveTo) Then
'Sacuvajmo tekuci record pre pomeranja na novi:
If Me.Dirty Then
Me.Dirty = False
End If

'Kloniramo formin recordset i tu napravimo pretragu:
Set rs = Me.RecordsetClone
rs.FindFirst "[CustomerID] = " & Me!cboMoveTo
If rs.NoMatch Then
'za slucaj da ne nadjemo record
MsgBox "Trazeni slog nije nadjen. Da nije mozda Filter aktivan?"
Else
'Ovim pozicioniramo formu na zeljeni record
Me.Bookmark = rs.Bookmark
End If
Set rs = Nothing
End If
End Sub

Upozorenje: ako je CustomerID Text polje, onda treba uotrebiti znake navoda kod pretrazivanja:

rs.FindFirst "[CustomerID] = """ & Me!cboMoveTo & """"