[ milos_pan @ 16.03.2012. 21:59 ] @
da li moze da se uradi sabiranje u sledecem slucaju?
sadrzaj u jednoj celiji je npr. 1p3
sadrzaj u drugoj celiji je npr. 1p5
zelim da saberem samo 3+5
trazio saam u ekselovoj bibliji i na forumu ali nisam nasao ovakav slucaj
HVALA
[ timmy @ 16.03.2012. 22:08 ] @
Recimo da je prvi unos (1p3) u A1 a drugi (1p5) u A2

Tvoja formula bi mogla da bude

Code:
=RIGHT(A1)+RIGHT(A2)


Ali obrati paznju da ovakva formula sabira samo poslednje cifre iz celija A1 i A2, dok bi (malo duza) formula

Code:
=RIGHT(A1,LEN(A1)-FIND("p",A1))+RIGHT(A2,LEN(A2)-FIND("p",A2))


sabirala sve sto pise iza slova 'p' iz prve i druge celije.

pozdrav
[ milos_pan @ 17.03.2012. 00:24 ] @
moje pitanje nije bilo potpuno. mislio sam da cu pronaci resenje ako znam osnov.
potrebno je da saberem brojeve u vise celija,tacnije u 30 celija. nerealno je da 30 puta koristim znak +
mozda postoji nesto kao naprimer sum(a2:m2)
[ 3okc @ 17.03.2012. 06:10 ] @
Dobio si rešenje za član1+član2 a ako bi hteo rešenje za opseg, uzmi onaj deo sa član1 i referencu zameni sa opsegom pa sve ubaci u SUM.

Možda će ti trebati matrični unos (Ctrl+Shift+Enter).
[ milos_pan @ 17.03.2012. 07:41 ] @
hvala na pomoci ali nesto ne funkcionise. ja sam razumeo ovako =sum(right(a1:c1)
ako moze objasnjenje na primeru.
HVALA
[ Brodoplovac @ 17.03.2012. 11:24 ] @
Evo ovako radi (matrična formula):
=SUMPRODUCT(RIGHT(C7:C10;1)*1)
[ timmy @ 17.03.2012. 16:58 ] @
Ili nesto kao

Code:
=SUM(1*RIGHT(A1:A4,LEN(A1:A4)-FIND("p",A1:A4)))


Zavrseno sa Ctrl+Shift+Enter

[ milos_pan @ 17.03.2012. 19:12 ] @
hvala svima.
ali u mojoj tabeli postoje brojevi i prazne celije koje remete ovu funkciju pa je ne mogu primeniti.
zato mi je pala na pamet druga ideja
celije sam formatirao da broj automatski menja boju u crvenu.
ali kada sam pokusao da napravim formulu =if(sum(a1:c1;;999) ne funkcionise
pitanje!
kako da sabiram samo brojeve koji su npr. crvene boje 1 (crveno) 2(normalno) 3 (crveno) itd
Hvala

[Edit: Tagovi]

[Ovu poruku je menjao 3okc dana 17.03.2012. u 20:49 GMT+1]
[ 3okc @ 17.03.2012. 20:49 ] @
Code:
=SUM(1*(SUBSTITUTE(IF(ISTEXT(A1:A4);A1:A4;"p0");
LEFT(IF(ISTEXT(A1:A4);A1:A4;"p0"); SEARCH("p";IF(ISTEXT(A1:A4);A1:A4;"p0")));"")))


Edit: Isto, malo drugačije:
Code:
=SUM(IF(ISNUMBER(FIND("p";A1:A4));
RIGHT(A1:A4;LEN(A1:A4)-FIND("p";A1:A4));0)*ROW(1:4)/ROW(1:4))


[Ovu poruku je menjao 3okc dana 19.03.2012. u 14:35 GMT+1]