Postavljanje jpg fajla kao pozadine forme (svake) ???

[ gorancho @ 25.01.2014. 14:29 ] @

Želeo bi da na disku imam jedan fajl npr c:/user/sablon/pozadina1.jpg i da njega uvozim za pozadinu svake forme i to kao streč i send to back.
Verujem da može ali kako ???

[ SLOJ.1973 @ 25.01.2014. 18:59 ] @

Napravi novi modul i u njemu ovu funkciju:

Code:
Option Compare Database

Function Pozadina()
Dim intNumOfForms As Integer
Dim intFrmCtr As Integer
Dim strFormName As String

intNumOfForms = CurrentDb.Containers("Forms").Documents.Count

For intFrmCtr = 0 To intNumOfForms - 1
  strFormName = CurrentDb.Containers("Forms").Documents(intFrmCtr).Name
    DoCmd.OpenForm strFormName, acDesign, , , acFormEdit, acHidden
      Forms(strFormName).Picture = "D:\slike\preuzimanje.bmp" ' putanja do tvoje slike
      Forms(strFormName).PictureSizeMode = 1    'Stretch
       DoCmd.Close acForm, strFormName, acSaveYes
Next

End Function

Zatim napravi macro pod nazivom AUTOEXEC i pozovi ovu funkciju (odaberi RunApp i dole u FunctionName pronadji funkciju Pozadina.Pozdrav.

[ SLOJ.1973 @ 25.01.2014. 19:38 ] @

Ako ne budes zeleo da bas sve forme imaju istu sliku ,onda u Dizajn forme,postavis za Tag recimo 1 onim formama,koje zelis da imaju tu sliku za pozadinu,a ostalim formama ostavis polje Tag prazno i onda napravis sve isto kao i u gornjem postu,samo sa malom izmenom funkcije:

Code:
Function Pozadina()
Dim intNumOfForms As Integer
Dim intFrmCtr As Integer
Dim strFormName As String

intNumOfForms = CurrentDb.Containers("Forms").Documents.Count

For intFrmCtr = 0 To intNumOfForms - 1
  strFormName = CurrentDb.Containers("Forms").Documents(intFrmCtr).Name

    DoCmd.OpenForm strFormName, acDesign, , , acFormEdit, acHidden
    If Forms(strFormName).Tag = "1" Then ' Ovo je deo koji proverava vrednost osobine Tag na formi
      Forms(strFormName).Picture = "D:\slike\preuzimanje.bmp" ' Putanja do tvoje slike
      Forms(strFormName).PictureSizeMode = 1    'Stretch
       DoCmd.Close acForm, strFormName, acSaveYes
       End If
Next

End Function

[ gorancho @ 27.01.2014. 23:00 ] @

Hvala puno. To je to.
Moraću malo bolje da razumem kod jer

JEDAN OVAO DOBAR ODGOVO RAĐA JOŠ 1000 PITANJA.