[ babayaro961 @ 18.04.2018. 21:12 ] @
U brojnim besplatnim obrascima aplikacija koje "idu uz" MS Office paket, postoji tabela "Contact" i forma "Contact Details" gde se, uz upisanu adresu kontakta, pomoću dugmeta "Click to Map", može izaći na bing.com mapu
koja je pozicionirana na zadatoj adresi. Dakle, ne raid se o embedovanju, već o direktnom povezivanju sa bing.com/maps.Za izvršenje ove naredbe koristi se modul "modMapping", a i sve je dobro objašnjeno na Microsoft-ovom sajtu:

Function OpenMap(Address, City, State, Zip, CountryOrRegion)

Dim strAddress As String
strAddress = Nz(Address)
strAddress = strAddress & IIf(strAddress = "", "", ", ") & Nz(City)
strAddress = strAddress & IIf(strAddress = "", "", ", ") & Nz(State)
strAddress = strAddress & IIf(strAddress = "", "", ", ") & Nz(Zip)
strAddress = strAddress & IIf(strAddress = "", "", ", ") & Nz(CountryOrRegion)

If strAddress = "" Then
MsgBox "There is no address to map."
Else
Application.FollowHyperlink "http://maps.live.com/default.aspx?where1=" & strAddress
End If
End Function

Da li je nekome poznato kako se umesto bing.com-a na ovaj način mogu iskoristiti google mape, jer su one, barem što se tiče unutrašnjosti, preciznije u povezivanju sa zadatom adresom.
[ djux66 @ 21.04.2018. 11:16 ] @
Može i sa google mapama:

Code:

Option Compare Database
Option Explicit

Public Function SearchMaps(Street As String, Optional Number As String = "", Optional City As String = "", _
    Optional State As String = "", Optional Country As String = "", Optional PoBox As String = "") As String
    
    Dim url, parameter, delimiter As String
    url = "https://google.com/maps/search/"
    delimiter = "+"
    
    
    If (Number & "" <> "") Then
        parameter = parameter & Number & delimiter
    End If

    If (Street & "" <> "") Then
        parameter = parameter & Replace(Street, " ", "+") & delimiter
    End If

    If (City & "" <> "") Then
        parameter = parameter & Replace(City, " ", "+") & delimiter
    End If

    If (State & "" <> "") Then
        parameter = parameter & State & delimiter
    End If

    If (PoBox & "" <> "") Then
        parameter = parameter & PoBox & delimiter
    End If
    
    If (Country & "" <> "") Then
        parameter = parameter & Replace(Country, " ", "+") & delimiter
    End If


    'trim delimiter
    If (Len(parameter) > Len(delimiter)) Then
        parameter = Left(parameter, Len(parameter) - Len(delimiter))
        url = url & parameter
        Debug.Print url
        SearchMaps = url
    Else
       Debug.Print "no search criteria"
       SearchMaps = ""
    End If
    
End Function
[ @ 25.04.2018. 20:00 ] @
http://icentar.ba/showtopic.php?id=2114
[ babayaro961 @ 25.04.2018. 20:35 ] @
Nije me bilo duže vreme na netu, sa zakašnjenjem zahvaljujem na odgovoru. djux66, može li nešto konkretnije uz ovaj primer?


[Ovu poruku je menjao babayaro961 dana 26.04.2018. u 09:37 GMT+1]

[Ovu poruku je menjao babayaro961 dana 26.04.2018. u 09:38 GMT+1]
[ babayaro961 @ 25.04.2018. 21:12 ] @
Citat:
Dexxxl :
http://icentar.ba/showtopic.php?id=2114


Na žalost, ovo kod mene uopšte ne funkcioniše, stano mi javlja neke greške u kodu
[ djux66 @ 26.04.2018. 21:58 ] @
Nešto ne mogu da otvorim tvoj primer, nema veze postaviću ja moj primer pa pogledaj.
Ja sam ovo pravio sa web controlom na formi ali može da se koristi i Application.FollowHyperlink da otvaraš u pretraživaču

Code:
Public Function SearchMaps(Street As String, Optional Number As String = "", Optional City As String = "", _
    Optional State As String = "", Optional Country As String = "", Optional PoBox As String = "")


Funkciju ne moraš da prepravljaš, ako ti je Address ulica i broj zajedno, stavi to samo kao parametar Street, a Number preskoči, trebalo bi da radi.

Bat fajl koji je u prilogu registruje IE11 kao web kontrolu, pošto access po difoltu koristi IE7. Ako želiš da se mape lepo prikazuju uokviru web kontrole na formi pokreni bat fajl, ako ne ignoriši...

[ babayaro961 @ 27.04.2018. 07:02 ] @
Aferim! To je to! Samo sam polja "Street" i "PoBox" zamenio nazivima svojih polja i radi ko novo :). Veliko hvala.

[Ovu poruku je menjao babayaro961 dana 27.04.2018. u 10:26 GMT+1]