VB6 kod koji dodaje command button na odredjeno mesto

[ Burgos @ 19.05.2004. 18:07 ] @

Treba mi kod koji dodaje command button na odredjno mesto (487x87) i daje mu odredjeni naziv i caption. Da li je to moguce uraditi u VB6?

[ mladenovicz @ 19.05.2004. 18:13 ] @

Naziv ne mozes da mu setujes.

ovo moze d se napravi nizom kontrola (napravi dugme cmdButton i setuj mu index na 0). kad ti zatreba novi buton uradi load:

Code:

    Load cmdButton(1)
    cmdButton(1).Move 487, 47
    cmdButton(1).Caption = "AAAAA"
    cmdButton(1).Visible = True

Za ovo mozda mozes da koristis i dugme koje se ne vidi a kd ti zatreba prikazes ga (Visible property)

[ Burgos @ 20.05.2004. 12:21 ] @

OK to mi je jasno, hvala!
E sada zelim da mi na pritisak otvori EXE program cija je lokacija navedena u nekom stringu (slicno Start - Run). Hvala.

[ mladenovicz @ 20.05.2004. 12:29 ] @

Code:

Shell(pathname[,windowstyle])

[ Burgos @ 20.05.2004. 12:48 ] @

Hvala. A sta je Window Style?

[ Burgos @ 20.05.2004. 12:50 ] @

I kako da uradim da mi se po izvrsenju prozora stari prozor minimizira i kada se prozor zatvori ponovo da se maximizira?
I to bi bilo to......do sutra :-).

[ mladenovicz @ 20.05.2004. 12:54 ] @

Kad krenes da kucas shell komandu i posle patha otkucas zarez VB ce ti ponuditi moguce vrednosti (normal, maximized, minimized, sa fokusom, bez fokusa). Videces vec, ili pogledaj u MSDNu.

[ Burgos @ 20.05.2004. 12:55 ] @

hvala ti mladenovicz. Nemas pojma koliko si mi pomogao!

[ mladenovicz @ 20.05.2004. 13:14 ] @

Citat:

I kako da uradim da mi se po izvrsenju prozora stari prozor minimizira i kada se prozor zatvori ponovo da se maximizira?

Minimizujes prozor, pokrenes program sa shell, enableujes timer (stavi interval recimo 1000ms). Shell ti vraca id procesa, a na timeru proveravas da li je medju aktivnim procesima onaj koji si pokrenuo sa shell. Cim ga nema maximizujes prozor.

Code:

Const TH32CS_SNAPHEAPLIST = &H1
Const TH32CS_SNAPPROCESS = &H2
Const TH32CS_SNAPTHREAD = &H4
Const TH32CS_SNAPMODULE = &H8
Const TH32CS_SNAPALL = (TH32CS_SNAPHEAPLIST Or TH32CS_SNAPPROCESS Or TH32CS_SNAPTHREAD Or TH32CS_SNAPMODULE)
Const TH32CS_INHERIT = &H80000000
Const MAX_PATH As Integer = 260
Private Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type
Private Declare Function CreateToolhelp32Snapshot Lib "Kernel32" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Private Declare Function Process32First Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function Process32Next Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass As Long)

Private m_ProcID As Variant

Private Sub Form_Load()
    Timer1.Enabled = False
    Me.WindowState = vbMinimized
    m_ProcID = Shell("notepad.exe", vbNormalFocus)
    If m_ProcID <> 0 Then
        Timer1.Enabled = True
    Else
        ' shell calll failed
       Me.WindowState = vbMaximized
    End If

End Sub

Private Sub Timer1_Timer()

    Dim hSnapShot As Long, uProcess As PROCESSENTRY32
    Dim bFound As Boolean

    'Takes a snapshot of the processes and the heaps, modules, and threads used by the processes
    hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0&)
    'set the length of our ProcessEntry-type
    uProcess.dwSize = Len(uProcess)
    'Retrieve information about the first process encountered in our system snapshot
    r = Process32First(hSnapShot, uProcess)
    'set graphics mode to persistent
    Me.AutoRedraw = True
    bFound = False
    Do While r
        If uProcess.th32ProcessID = m_ProcID Then
            r = 0
            bFound = True
        Else
            'Retrieve information about the next process recorded in our system snapshot
            r = Process32Next(hSnapShot, uProcess)
        End If
    Loop
    'close our snapshot handle
    CloseHandle hSnapShot
    If Not bFound Then
        Timer1.Enabled = False
        Me.WindowState = vbMaximized
    End If
End Sub

[ Burgos @ 20.05.2004. 13:34 ] @

Thanks, ali pomoglo je samo i style
vbmaximizedFocus.