[ andrejas33 @ 19.08.2004. 21:46 ] @
Pošto u top temi nisam pronašao odgovor na moj problem molim pomoć.

Kako da iz fajla čitam text i recimo prvo liniju zapišem u TextBox1,drugu u
TextBox2, a sve ostale linije u TextBox3?

Nemam problema sa čitanjem liniju po liniju, ali kako da skombiniram ovo?

Nadam se, da mi zbog takvog bezveznog pitanje nečete odmah brisati temu.
Molim Vas, da mi je pustite bar toliko, da dobijem odgovor.

Hvala
[ djordje @ 20.08.2004. 01:38 ] @
Pojasni malo, nisam te bas razumeo, ali evo ti jedan koristan link

http://www.juicystudio.com/tutorial/vb/files.asp
[ mladenovicz @ 20.08.2004. 09:51 ] @
Linije loadujes u niz stringova i posle radis sa nizom

Code:

Private Sub Form_Load()
Dim oFSO        As Scripting.FileSystemObject
Dim oTextStream As Scripting.TextStream
Dim arrLines()  As String
Dim NumLines    As Long
Dim i           As Long

    NumLines = 0

    Set oFSO = New Scripting.FileSystemObject
    Set oTextStream = oFSO.OpenTextFile("C:\test.txt", _
                                           ForReading, _
                                           True, _
                                           TristateFalse)
    
        
    While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        ReDim Preserve arrLines(NumLines)
        arrLines(NumLines) = oTextStream.ReadLine
    Wend
    
    oTextStream.Close
    
    Set oTextStream = Nothing
    Set oFSO = Nothing
    
    If NumLines >= 1 Then Text1.Text = arrLines(1)
    If NumLines >= 2 Then Text2.Text = arrLines(2)
    
    For i = 3 To NumLines
        Text3.Text = Text3.Text & arrLines(i) & vbCrLf
    Next
    
End Sub

[ mladenovicz @ 20.08.2004. 09:54 ] @
ili bez niza

Code:

Private Sub Form_Load()
Dim oFSO        As Scripting.FileSystemObject
Dim oTextStream As Scripting.TextStream
Dim strLine     As String
Dim NumLines    As Long
Dim i           As Long

    NumLines = 0

    Set oFSO = New Scripting.FileSystemObject
    Set oTextStream = oFSO.OpenTextFile("C:\test.txt", _
                                           ForReading, _
                                           True, _
                                           TristateFalse)

        
    While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        strLine = oTextStream.ReadLine
        Select Case NumLines
            Case 1
                Text1.Text = strLine
            Case 2
                Text2.Text = strLine
            Case Is > 2
                Text3.Text = Text3.Text & strLine & vbCrLf
        End Select
    Wend
    
    oTextStream.Close
    
    Set oTextStream = Nothing
    Set oFSO = Nothing
    
    
End Sub

[ andrejas33 @ 20.08.2004. 11:44 ] @
Hvala na primerima, ali ja još uvjek imam problem.
Do sada sam uvjek čitao fajle sa " Open "c:\XXX.txt" For Imput As ..."
i zato mi taj FSO pravi probleme.

Kad startujem tvoj primer, onda mi javi grešku:

Dim oFSO As Scripting.FileSystemObject


Greška: User - defined type not defined

Dali trebam neki DLL ili šta?

Molim još pomoć!

Hvala!
[ mladenovicz @ 20.08.2004. 11:48 ] @
Treba ti referenca na Microsoft Scripting Runtime. (Project->References)
[ andrejas33 @ 20.08.2004. 12:08 ] @


Uspelo!!

Puno hvala na pomoći i lep pozdrav!
[ Shadowed @ 20.08.2004. 12:18 ] @
@mldenovicz. Ovo mi je malo neobicno. Cemu
Code:
While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        strLine = oTextStream.ReadLine
        Select Case NumLines
            Case 1
                Text1.Text = strLine
            Case 2
                Text2.Text = strLine
            Case Is > 2
                Text3.Text = Text3.Text & strLine & vbCrLf
        End Select
    Wend

Zar nije jednostavnije i brze (za izvrsavanje)
Code:
Text1.Text = oTextStream.ReadLine
Text2.Text = oTextStream.ReadLine
While Not oTextStream.AtEndOfStream
    Text3.Text = Text3.Text & oTextStream.ReadLine & vbCrLf
Wend
[ mladenovicz @ 20.08.2004. 12:29 ] @
@Shadowed:
U pravu si. Ovo sam pisao pre nego sto sam popio kafu (ako je neko opravdanje)
Nekad se bas nacudim kodu koji napisem.

EDIT: Samo sto ovo tvoje parce koda podrazumeva da u fajlu postoje bar dve linije